home *** CD-ROM | disk | FTP | other *** search
/ The World of Computer Software / The World of Computer Software.iso / cmsrc392.zip / ITALL.MF < prev    next >
Text File  |  1992-03-30  |  21KB  |  460 lines
  1. % Computer Modern Italic lower case:
  2. % This lowercase italic alphabet was prepared by D. E. Knuth in December, 1979,
  3. % inspired by the Monotype faces used in {\sl The Art of Computer Programming}.
  4. % The programs were revised for the new \MF\ conventions in 1985.
  5.  
  6. % Character codes \0141 through \0172 are generated.
  7.  
  8. cmchar "Italic letter a";
  9. beginchar("a",9u#,x_height#,0);
  10. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  11. adjust_fit(0,0); pickup fine.nib;
  12. pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
  13. pos4(stem,0); x4=x0; y4+.5stem=vround .98h;
  14. x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
  15. rt x4r=hround(w-2.5u+.5stem);
  16. top y1r=h+oo; bot y3r=-oo; y0=y2=.5[y1,y3];
  17. filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
  18.  & pulled_arc.e(2,3) & super_arc.e(3,0);  % bowl
  19. x5=x4; x7=w; hook_out(5,6,7);  % closing hook
  20. filldraw circ_stroke z4e--z5e;  % stem
  21. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  22. penlabels(0,1,2,3,4,5,6,7); endchar;
  23.  
  24. cmchar "Italic letter b";
  25. beginchar("b",8u#,asc_height#,0);
  26. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  27. adjust_fit(0,0); pickup tiny.nib;
  28. pos1(stem,0); pos2(stem,0); x1=x2;
  29. lft x1l=hround(1.5u-.5stem); top y1=h; y2=.5x_height;
  30. filldraw stroke z1e--z2e;  % stem
  31. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  32. pickup fine.nib; pos2'(stem,-180); pos3(vair,-90);
  33. pos4(curve,0); pos5(vair,90); pos0(hair,180);
  34. z0=z2=z2'; x3=x5=.5[x2,x4]; rt x4r=hround(w-1.5u+.5curve);
  35. bot y3r=-oo; top y5r=x_height+oo; y4=y2;
  36. filldraw stroke pulled_arc.e(2',3) & pulled_arc.e(3,4)
  37.  & pulled_arc.e(4,5) & super_arc.e(5,0);  % bowl
  38. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  39. penlabels(0,1,2,3,4,5); endchar;
  40.  
  41. cmchar "Italic letter c";
  42. beginchar("c",8u#,x_height#,0);
  43. italcorr if math_fitting:1/3x_height#*slant else:x_height#*slant-u# fi;
  44. adjust_fit(0,0); pickup fine.nib;
  45. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  46. pos3(curve,180); pos4(vair,270); pos5(hair,320);
  47. x2=x4=.5(w+u); rt x1r=max(rt x2,hround(w-u))+eps;
  48. lft x3r=hround(1.5u-.5curve); x5r=good.x(w-eps); x6=x5;
  49. y1=.5[bar_height,h]; top y2r=h+oo; bulb(2,1,0);  % bulb
  50. bot y4r=-oo; y3=.5[y2,y4]; top y5l=vround .5bar_height; y6=bar_height;
  51. path p; p=z4{right}..z5..z6;
  52. filldraw stroke pulled_arc.e(2,3)
  53.  & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
  54. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  55. penlabels(0,1,2,3,4,5,6); endchar;
  56.  
  57. cmchar "Italic letter d";
  58. beginchar("d",9u#,asc_height#,0);
  59. italcorr max(1/3x_height#*slant+.5hair#+.5u#,
  60.   h#*slant+.5stem#-2u#) if math_fitting:-.5u# fi;
  61. adjust_fit(0,0); pickup fine.nib;
  62. pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
  63. x0=x4; x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
  64. x4+.5stem=hround(w-2.5u+.5stem);
  65. top y1r=x_height+oo; bot y3r=-oo; y0=y2=.5[y1,y3];
  66. filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
  67.  & pulled_arc.e(2,3) & super_arc.e(3,0);  % bowl
  68. x5=x0; x7=w; hook_out(5,6,7);  % closing hook
  69. pickup tiny.nib; pos5'(stem,0); pos4(stem,0);
  70. z5'=z5; top y4=h; filldraw stroke z4e--z5'e;  % stem
  71. sloped_serif.l(4,5',a,1/3,jut,serif_drop);  % serif
  72. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  73. penlabels(0,1,2,3,4,5,6,7); endchar;
  74.  
  75. cmchar "Italic letter e";
  76. beginchar("e",8u#,x_height#,0);
  77. italcorr max(1/3x_height#*slant,x_height#*slant+.5(.2[hair#,stem#])-u#);
  78. adjust_fit(0,0); pickup fine.nib;
  79. numeric heavy_hair; heavy_hair=hround .2[hair,stem];
  80. pos0(vair,-90); pos1(heavy_hair,0); pos2(vair,90);
  81. pos3(curve,180); pos4(vair,270); pos5(hair,320);
  82. x0=rt x3l; rt x1r=hround(w-1.5u+.5heavy_hair); x2=x4=.5(w+u);
  83. lft x3r=hround(1.5u-.5curve); x5r=good.x(w-eps); x6=x5;
  84. y0=y3=y6=bar_height; y1=.5[y0,y2]; top y2r=h+oo; bot y4r=-oo;
  85. top y5l=vround .5bar_height; path p; p=z4{right}..z5..z6;
  86. filldraw stroke z0e{right}...z1e{up}...pulled_arc.e(2,3)
  87.  & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
  88. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  89. penlabels(0,1,2,3,4,5,6); endchar;
  90.  
  91. cmchar "Italic letter f";
  92. beginchar("f",max(1.5u#,stem#)+max(3.5u#,2flare#),asc_height#,desc_depth#);
  93. italcorr asc_height#*slant+.75u#;
  94. adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
  95. numeric theta; z88=(.5w-.5u,h); z89=(.5w+.5u,-d); theta=angle(z88-z89);
  96. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  97. pos3(.5[hair,stem],180); pos4(stem,theta+90);
  98. pos5(stem,theta-90); pos6(.5[hair,stem],0);
  99. pos7(vair,-90); pos8(hair,-180); pos9(flare,-180);
  100. rt x1r=hround(w+.25u); lft x8r=hround-.35u; x2=.6[x1,x4]; x7=.6[x8,x5];
  101. y9-.5flare=vround -.85d; y2-y0=y9-y7; top y2r=h+oo; bot y7r=-d-oo;
  102. y4=.25[x_height,h]; y5=.5[-d,y4];
  103. z4=whatever[z88,z89]; z5=whatever[z88,z89];
  104. x3=.8[x2+x4-x88,x88]; x6=.8[x7+x5-x89,x89]; y3=.8[y4,y2]; y6=.8[y5,y7];
  105. bulb(2,1,0); bulb(7,8,9);  % bulbs
  106. filldraw stroke z2e{left}...z3e...{z89-z88}z4e;  % upper arc
  107. filldraw z4r--z5l--z5r--z4l--cycle;  % stem
  108. filldraw stroke z5e{z89-z88}...z6e...{left}z7e;  % lower arc
  109. pickup crisp.nib; pos20(bar,90); pos21(bar,90);
  110. top y20r=top y21r=x_height;
  111. lft x20=lft x4r-.5stem-u; rt x21=rt x4l+.5stem+1.5u;
  112. filldraw stroke z20e--z21e;  %  crossbar
  113. math_fit(desc_depth#*slant+u#,x_height#*slant);
  114. penlabels(0,1,2,3,4,5,6,7,8,9,20,21,88,89); endchar;
  115.  
  116. cmchar "Italic letter g";
  117. beginchar("g",8u#,x_height#,desc_depth#);
  118. italcorr x_height#*slant+.5stem#-u#;
  119. adjust_fit(0,0); pickup fine.nib;
  120. pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
  121. x0=x4; x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
  122. x4+.5stem=hround(w-1.5u+.5stem);
  123. top y1r=h+oo; bot y3r=0; y0=y2=.5[y1,y3];
  124. filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
  125.  & pulled_arc.e(2,3) & super_arc.e(3,0);  % bowl
  126. pos4(stem,0); y4+.5stem=vround .98h;
  127. pos5(stem,0); x5=x4; y5=-1/3d;
  128. pos6(vair,-90); pos7(hair,-180); pos8(flare,-180);
  129. bot y6r=-d-oo; y8-.5flare=vround -.9d;
  130. lft x8r=hround(2u-.5flare); x6=x1; bulb(6,7,8);  % bulb
  131. filldraw circ_stroke z4e---z5e...{left}z6e;  % stem and arc
  132. math_fit(-min(.3x_height#*slant+.5curve#-u#,1.5u#-desc_depth#*slant),
  133.  ic#-1/3x_height#*slant); penlabels(0,1,2,3,4,5,6,7,8); endchar;
  134.  
  135. cmchar "Italic letter h";
  136. beginchar("h",9u#,asc_height#,0);
  137. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  138. adjust_fit(0,0); pickup tiny.nib;
  139. pos1(stem,0); pos2(stem,0); x1=x2;
  140. lft x1l=hround(1.5u-.5stem); top y1=h; y2-.5stem=-oo;
  141. filldraw circ_stroke z2e--z1e;  % left stem
  142. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  143. pickup fine.nib; x4+.5stem=hround(w-2.5u+.5stem);
  144. x5=x4-.25u; ital_arch(2,3,4);  % arch
  145. x7=w; hook_out(5,6,7)(skewed);  % closing hook
  146. filldraw stroke z4e{down}..{-u,-x_height}z5e;  % right stem
  147. math_fit(0,ic#); penlabels(1,2,3,4,5,6,7); endchar;
  148.  
  149. cmchar "Italic letter i";
  150. beginchar("i",5u#,min(asc_height#,10/7x_height#+.5flare#),0);
  151. italcorr max(1/3x_height#*slant+.5hair#+.5u#,h#*slant+.5flare#-2u#);
  152. adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
  153. x0=0; x5=w; x2=.5w+.25u; x3=.5w-.25u;
  154. hook_in(0,1,2)(skewed); hook_out(3,4,5)(skewed);  % hooks
  155. filldraw stroke z2e--z3e;  % stem
  156. pos8(flare,0); pos9(flare,90);
  157. x8=.5w if not monospace:-.4(h-x_height)*slant fi; top y9r=h+1;
  158. if bot y9l-top y1<slab: y9l:=min(y9r-eps,y1+fine+slab); fi
  159. x8=x9; y8=.5[y9l,y9r]; dot(8,9);  % dot
  160. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  161. penlabels(0,1,2,3,4,5,8,9); endchar;
  162.  
  163. cmchar "Italic letter j";
  164. beginchar("j",5u#,min(asc_height#,10/7x_height#+.5flare#),desc_depth#);
  165. italcorr h#*slant+.5stem#-u#;
  166. adjust_fit(if monospace:2u#,.5u# else: 0,0 fi); pickup fine.nib;
  167. x0=0; x2=x3; pos3(stem,0); lft x3l=hround(w-1.5u-.5stem);
  168. hook_in(0,1,2);  % opening hook
  169. pos4(vair,-90); pos5(hair,-180); pos6(flare,-180);
  170. bot y3=-1/3d; bot y4r=-d-oo; y6-.5flare=-vround.9d;
  171. x4=1/3(w-u); lft x5r=min(hround-.5u,lft x5r+x4-x5l-eps);
  172. filldraw stroke z2e---z3e...{left}z4e;  % stem and arc
  173. bulb(4,5,6);  % bulb
  174. pos8(flare,0); pos9(flare,90);
  175. rt x8r=rt x2r if not monospace:-.6(h-x_height)*slant fi; top y9r=h+1;
  176. if bot y9l-top y1<slab: y9l:=min(y9r-eps,y1+fine+slab); fi
  177. x8=x9; y8=.5[y9l,y9r]; dot(8,9);  % dot
  178. math_fit(desc_depth#*slant,x_height#*slant+.5stem#-u#);
  179. penlabels(0,1,2,3,4,5,6,8,9); endchar;
  180.  
  181. cmchar "Italic letter k";
  182. beginchar("k",8u#,asc_height#,0);
  183. italcorr x_height#*slant;
  184. adjust_fit(0,0); pickup tiny.nib;
  185. pos1(stem,0); pos2(stem,0); x1=x2;
  186. lft x1l=hround(1.5u-.5stem); top y1=h; y2-.5stem=-oo;
  187. filldraw circ_stroke z2e--z1e;  % left stem
  188. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  189. pickup fine.nib; pos3(vair,90); x3=x1; y3=bar_height;
  190. pos4(vair,90); x4=w-2u; top y4r=x_height+oo;
  191. filldraw stroke z3e{right}..{right}z4e;  % upper diagonal
  192. pos5(hair,0); pos6(flare,0);
  193. rt x5r=hround(w-.5u); y5+.5flare=vround(bot y4l-.03x_height);
  194. bulb(4,5,6);  % bulb
  195. pos7(stem,0); pos8(vair,90); pos9(hair,180);
  196. x9+.5hair=hround(w+.5hair-eps); y9=1/3x_height;
  197. lft x7l=hround(w-2.75u-.5stem); y7=1/2y3; x8=w-1.2u; bot y8l=-oo;
  198. filldraw stroke z3e{right}...z7e{down}
  199.  ...z8e{right}...{up}z9e;  % lower diagonal
  200. math_fit(0,1/3x_height#*slant+.5hair#+.5u#);
  201. penlabels(1,2,3,4,5,6,7,8,9); endchar;
  202.  
  203. cmchar "Italic letter l";
  204. beginchar("l",4u#,asc_height#,0); l_width#:=4u#;
  205. italcorr max(1/3x_height#*slant+.5hair#+.5u#,
  206.  asc_height#*slant+.5stem#-2u#) if math_fitting:+.5u# fi;
  207. adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
  208. x2-.5stem=hround(1.5u-.5stem); x4=w; hook_out(2,3,4);  % closing hook
  209. pickup tiny.nib; pos1(stem,0); pos2'(stem,0); z2'=z2;
  210. top y1=h; x1=x2; filldraw stroke z1e--z2'e;  % stem
  211. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  212. math_fit(-.5u#,1/3x_height#*slant+.5hair#+u#); penlabels(1,2,3,4); endchar;
  213.  
  214. cmchar "Italic letter m";
  215. beginchar("m",15u#,x_height#,0);
  216. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  217. adjust_fit(if monospace:-1.5u#,-2u# else: 0,0 fi); pickup fine.nib;
  218. numeric shaved_stem; shaved_stem=mfudged.stem;
  219. save stem; stem=shaved_stem;
  220. pos2(stem,0); x1=x2;
  221. if monospace: pos1(stem,0); lft x1l=hround(2.5u-.5stem); top y1=h;
  222. else: x0=0; lft x2l=hround(2.5u-.5stem);
  223.  hook_in(0,a,1); fi  % opening hook
  224. y2-.5stem=-oo; filldraw circ_stroke z2e--z1e;  % left stem
  225. x4+.5stem=hround(.5w+.5stem); ital_arch(2,3,4);  % left arch
  226. pos5(stem,0); y5=y2; x5=x4;
  227. filldraw circ_stroke z5e--z4e;  % middle stem
  228. x7+.5stem=hround(w-2.5u+.5stem);
  229. x8=x7-.25u; ital_arch(5,6,7);  % right arch
  230. if monospace: pos9(vair,90); x9=good.x .5[x8,w]; bot y9l=0; y8=1/3h;
  231.  pos8(stem,0); filldraw stroke z8e{-u,-x_height}...{right}z9e; % terminal
  232. else: x9=w; hook_out(8,b,9)(skewed); fi  % closing hook
  233. filldraw stroke z7e{down}..{-u,-x_height}z8e;  % right stem
  234. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  235. penlabels(0,a,1,2,3,4,5,6,7,8,9); endchar;
  236.  
  237. cmchar "Italic letter n";
  238. beginchar("n",10u#,x_height#,0);
  239. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  240. adjust_fit(0,0); pickup fine.nib;
  241. x0=0; x1=x2; pos2(stem,0); lft x2l=hround(2.5u-.5stem); y2-.5stem=-oo;
  242. hook_in(0,a,1);  % opening hook
  243. filldraw circ_stroke z2e--z1e;  % left stem
  244. x4+.5stem=hround(w-2.5u+.5stem); x5=x4-.25u; ital_arch(2,3,4);  % arch
  245. x7=w; hook_out(5,6,7)(skewed);  % closing hook
  246. filldraw stroke z4e{down}..{-u,-x_height}z5e;  % right stem
  247. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  248. penlabels(0,a,1,2,3,4,5,6,7); endchar;
  249.  
  250. cmchar "Italic letter o";
  251. beginchar("o",9u#,x_height#,0);
  252. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  253. adjust_fit(0,0); pickup fine.nib;
  254. pos1(vair,90); pos2(curve,180); pos3(vair,270); pos4(curve,360);
  255. x1=x3=.5w; lft x2r=hround(1.5u-.5curve); x4=w-x2;
  256. top y1r=h+oo; y2=y4=.5[y1,y3]; bot y3r=-oo;
  257. filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  258.  & pulled_arc.e(3,4) & pulled_arc.e(4,1); % bowl
  259. math_fit(-.3x_height#*slant+.5curve#-u#,ic#); penlabels(1,2,3,4); endchar;
  260.  
  261. cmchar "Italic letter p";
  262. beginchar("p",9u#,x_height#,desc_depth#);
  263. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  264. adjust_fit(0,0); pickup fine.nib;
  265. x0=0; x2-.5stem=hround(2.5u-.5stem); hook_in(0,1,2);  % opening hook
  266. pos4(hair,-180); pos5(vair,-90); pos6(curve,0); pos7(vair,90);
  267. x4=x2; rt x6r=hround(w-1.5u+.5curve); x5=x7=.5[x4,x6];
  268. bot y5r=-oo; top y7r=h+oo; y4=y6=.5[y5,y7];
  269. filldraw stroke super_arc.e(4,5) & pulled_arc.e(5,6)
  270.  & pulled_arc.e(6,7) & super_arc.e(7,4);  % bowl
  271. pickup tiny.nib; pos2'(stem,0); pos3(stem,0);
  272. z2=z2'; x3=x2; bot y3=-d; filldraw stroke z2'e--z3e;  % stem
  273. dish_serif(3,2',a,1/3,.75jut,b,1/3,jut);  % serif
  274. math_fit(-min(2/3x_height#*slant-.5hair#-.5u#,
  275.  2u#-.5stem#-desc_depth#*slant),ic#);
  276. penlabels(0,1,2,3,4,5,6,7); endchar;
  277.  
  278. cmchar "Italic letter q";
  279. beginchar("q",8u#,x_height#,desc_depth#);
  280. italcorr x_height#*slant+.5stem#-u#;
  281. adjust_fit(0,0); pickup fine.nib;
  282. pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
  283. x0=x4; x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
  284. x4+.5stem=hround(w-1.5u+.5stem)+eps;
  285. top y1r=h+oo; bot y3r=-oo; y0=y2=.5[y1,y3];
  286. filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
  287.  & pulled_arc.e(2,3) & super_arc.e(3,0);  % bowl
  288. pickup tiny.nib; pos4(stem,0); pos5(stem,0);
  289. x4=x5; x6=x5r; top y6=h+oo; bot y4=-d;
  290. y5=ypart(((x4l,0)--(x4l,y6))intersectionpoint super_arc.r(0,1));
  291. filldraw z6{2(x5l-x6),y5-y6}...z5l---z4l--z4r--cycle;  % stem
  292. dish_serif(4,5,a,1/3,jut,b,1/3,jut);  % serif
  293. math_fit(-.3x_height#*slant+.5curve#-u#,ic#-1/3x_height#*slant);
  294. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  295.  
  296. cmchar "Italic letter r";
  297. beginchar("r",5.5u#+max(1.75u#,flare#),x_height#,0);
  298. italcorr x_height#*slant;
  299. adjust_fit(if monospace:.25u#,.5u# else: 0,0 fi); pickup fine.nib;
  300. x0=0; x2=x3; pos3(stem,0); lft x3l=hround(2.5u-.5stem); y3-.5stem=-oo;
  301. hook_in(0,1,2);  % opening hook
  302. filldraw circ_stroke z3e--z2e;  % left stem
  303. pos3'(hair,180); z3'=z3; pos4(vair,90); pos5(hair,0); pos6(flare,0);
  304. x4=w-.5u-max(1.75u,flare); rt x5r=hround(r-.5u); top y4r=h+oo;
  305. filldraw stroke z3'e{up}...z4e{right};  % link
  306. y6+.5flare=vround(bot y4l-.03x_height); bulb(4,5,6);  % bulb
  307. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#-.5u#);
  308. penlabels(0,1,2,3,4,5,6); endchar;
  309.  
  310. cmchar "Italic letter s";
  311. beginchar("s",5.25u#+max(1.75u#,flare#),x_height#,0);
  312. italcorr x_height#*slant-.5u#;
  313. adjust_fit(0,0); pickup fine.nib;
  314. numeric theta; theta=90-angle(40u,h); slope:=-h/40u;  % angle at middle
  315. pos2(vair,-90); pos0(max(fine.breadth,ess),theta); pos7(vair,-90);
  316. x2l=x0=x7=.5w; top y2l=h+oo; bot y7r=-oo;
  317. y0-.5ess=y7l+.55(y2r-y7l-ess);
  318. lft x3l=hround u-eps; rt x6r=hround(w-.5u)+eps;
  319. x3r-x3l=x6r-x6l=hround .5[vair,ess]-fine;
  320. ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
  321. ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
  322. interim superness:=more_super;
  323. filldraw stroke super_arc.e(2,3) & z3e{down}
  324.  ..z4e---z5e..z6e{down} & super_arc.e(6,7);  % main stroke
  325. pos1(hair,0); pos10(hround .75[hair,flare],0);
  326. pos2'(vair,90); z2'=z2;
  327. pos8(hair,-180); pos9(flare,-180);
  328. rt x10r=hround(w-u)+2eps; lft x9r=hround .5u-2eps; y10=.78h; y9=.25h;
  329. bulb(2',1,10); bulb(7,8,9);  % bulbs
  330. math_fit(0,ic#); penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  331.  
  332. cmchar "Italic letter t";
  333. beginchar("t",5.5u#,min(asc_height#,10/7x_height#),0);
  334. italcorr max(1/3x_height#*slant+.5hair#+.5u#,x_height#*slant-.25u#);
  335. adjust_fit(if monospace:u#,u# else:0,0 fi); pickup fine.nib;
  336. pos1(stem,0); lft x1l=hround(2u-.5stem); y1+.5stem=h+oo;
  337. x2=x1; x4=w; hook_out(2,3,4);  % closing hook
  338. filldraw circ_stroke z1e--z2e;  % stem
  339. pickup crisp.nib; pos5(bar,90); pos6(bar,90);
  340. lft x5=hround-.75u; rt x6=hround(w-.75u); top y5r=top y6r=x_height;
  341. filldraw stroke z5e--z6e;  % crossbar
  342. math_fit(1.25u#-x_height#*slant,ic#); penlabels(1,2,3,4,5,6); endchar;
  343.  
  344. cmchar "Italic letter u";
  345. beginchar("u",9.5u#,x_height#,0);
  346. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  347. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  348. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  349. hook_in(0,1,2)(skewed);  % opening hook
  350. pos2'(stem,-180); z2'=z2;
  351. pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
  352. pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
  353. x5=x6=x7; x9=w; hook_out(7,8,9);  % closing hook
  354. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
  355. filldraw stroke z2'e{-u,-x_height}
  356.  ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  357. filldraw circ_stroke z6e--z7e;  % right stem
  358. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  359. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  360.  
  361. cmchar "Italic letter v";
  362. beginchar("v",8u#,x_height#,0);
  363. italcorr x_height#*slant;
  364. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  365. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  366. hook_in(0,1,2)(skewed);  % opening hook
  367. pos2'(stem,-180); z2'=z2; pos4(vair,-90); pos5(hair,0);
  368. x4=.5w+u; rt x5r=hround(w-.5u); y3=.7[y4,y5]; bot y4r=-oo; y5=.57h;
  369. filldraw stroke z2'e{-u,-x_height}...super_arc.e(3,4)
  370.  ..tension atleast 1.05..{up}z5e; % left stem and arc
  371. v_bulb(5,6);  % closing bulb
  372. math_fit(-2/3x_height#*slant+.5hair#+.5u#,2/3ic#);
  373. penlabels(0,1,2,3,4,5,6); endchar;
  374.  
  375. cmchar "Italic letter w";
  376. beginchar("w",12u#,x_height#,0);
  377. italcorr x_height#*slant;
  378. adjust_fit(if monospace:-1.5u#,-u# else: 0,0 fi);
  379. pickup fine.nib; interim superness:=more_super; begingroup
  380. forsuffixes $=hair,stem: shaved$:=mfudged$; save $; $=shaved$; endfor
  381. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  382. if monospace: pos1(vair,90); x1=good.x .5[x0,x2]; top y1r=h; y2=2/3h;
  383.  pos2(stem,0); filldraw stroke z1e{right}...{-u,-x_height}z2e;
  384. else: hook_in(0,1,2)(skewed); fi  % opening hook
  385. pos2'(stem,-180); z2'=z2;
  386. pos4(vair,-90); pos5(hair,0);
  387. x4=.6[x2,x5]; x5=x6=x7; pos6(stem,-180); pos7(stem,-180);
  388. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h;
  389. rt x6l=hround(rt x6l+.5w+.75u-x6); y6+.5stem=h; y7=y3;
  390. pos8(vair,-90); pos9(hair,0);
  391. x8=w-2.75u; rt x9r=hround(w-.5u); bot y8r=-oo; y9=y5;
  392. filldraw stroke z2'e{-u,-x_height}
  393.  ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  394. filldraw circ_stroke z6e..super_arc.e(7,8)...{up}z9e;  % middle stem and arc
  395. v_bulb(9,10);  % closing bulb
  396. endgroup; math_fit(-2/3x_height#*slant+.5hair#+.5u#,3/4ic#);
  397. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  398.  
  399. cmchar "Italic letter x";
  400. beginchar("x",6.5u#+max(1.5u#,flare#),x_height#,0);
  401. italcorr max(1/3x_height#*slant+.5hair#+.5u#,x_height#*slant+.25u#);
  402. adjust_fit(0,0); pickup fine.nib;
  403. pos0(hair,180); pos1(vair,90); pos2(stem,0);
  404. pos3(stem,-180); pos4(vair,-90); pos5(hair,0);
  405. y0=y2=2/3h; y3=y5=1/3h; top y1r=h+oo; bot y4r=-oo;
  406. rt x2r=hround(.5w+.5stem-eps); x2=x3;
  407. x0-.5hair=hround-.5hair; x5+.5hair=hround(w+.5hair-eps);
  408. x1=.5[x0,x2]; x4=.5[x3,x5];
  409. filldraw stroke z0e{up}...pulled_arc.e(1,2); % opening hook
  410. filldraw z2l--z3r--z3l--z2r--cycle;  % stem
  411. filldraw stroke pulled_arc.e(3,4)...{up}z5e;  % closing hook
  412. pos3'(hair,180); pos6(hair,180); pos7(vair,90);
  413. pos8(hair,0); pos9(flare,0);
  414. x3'l=x6l=x3l; y3'=y3; y6=3/4h; x7=.5[x8,x2]; top y7r=h+oo;
  415. rt x8r=hround(w-.25u); y8+.5flare=vround(bot y7l-.03x_height);
  416. filldraw stroke z3'e---z6e...{right}z7e; bulb(7,8,9);  % upper link and bulb
  417. pos2'(hair,0); pos16(hair,0); pos17(vair,-90);
  418. pos18(hair,-180); pos19(flare,-180);
  419. x2'l=x16l=x2l; y2'=y2; y16=1/4h; x17=.5[x18,x3]; bot y17r=-oo;
  420. lft x18r=hround.25u; y18-.5flare=vround(top y17l+.03x_height);
  421. filldraw stroke z2'e---z16e...{left}z17e; bulb(17,18,19); % lower link and bulb
  422. math_fit(0,ic#); penlabels(0,1,2,3,4,5,6,7,8,9,16,17,18,19); endchar;
  423.  
  424. cmchar "Italic letter y";
  425. beginchar("y",8.5u#,x_height#,desc_depth#);
  426. italcorr x_height#*slant+.5stem#-u#;
  427. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  428. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  429. hook_in(0,1,2)(skewed);  % opening hook
  430. pos2'(stem,-180); z2'=z2;
  431. pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
  432. pos6(stem,0); rt x6r=hround(w-1.5u+.5stem);
  433. pos7(stem,0); pos8(vair,-90);
  434. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
  435. y7=0; bot y8r=-d-oo; x5=x6=x7; x8=.5w;
  436. pos9(hair,-180); pos10(flare,-180); y9=-.5d;
  437. lft x9r=hround(2.75u-.5flare); bulb(8,9,10);  % bulb
  438. filldraw stroke z2'e{-u,-x_height}
  439.  ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  440. filldraw circ_stroke z6e---z7e...{left}z8e;  % right stem and link
  441. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#-1/3x_height#*slant);
  442. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  443.  
  444. cmchar "Italic letter z";
  445. beginchar("z",5.5u#+max(1.5u#,stem#),x_height#,0);
  446. italcorr x_height#*slant+.5hair#;
  447. adjust_fit(if monospace:.5u#,.5u# else: 0,0 fi); pickup fine.nib;
  448. pos1(hair,0); pos2(stem,-90); pos3(vair,-90); pos4(hair,0);
  449. lft x1l=hround(u-.5hair); x2=2.5u; x3=w-2u; rt x4r=hround(w-.5u);
  450. top y1=.78h; top y2l=top y4=h+oo; y3=.825h;
  451. pos5(hair,0); pos6(vair,-90); pos7(stem,-90); pos8(hair,0);
  452. x5=x1; x6=2.5u; x7=w-2u; x8+.5hair=hround(w+.5hair-eps);
  453. bot y5=bot y7r=-oo; y6=.175h; bot y8=.31h;
  454. pair p; p=(z4-z5) yscaled 2;
  455. filldraw stroke z1e{up}...z2e{right}..z3e{right}...{p}z4e;  % upper bar
  456. filldraw stroke z5e{p}...z6e{right}..{right}z7e...{up}z8e;  % lower bar
  457. filldraw stroke z5e{p}..{p}z4e;  % diagonal
  458. math_fit(0,1/3x_height#*slant+.5hair#+.5u#);
  459. penlabels(1,2,3,4,5,6,7,8); endchar;
  460.